変数の型を数値で取得する方法

Contents
• 今回の目標
• VarType関数について
  • VarType関数とは
  • VarType関数の構文など
  • VarType関数の戻り値
• VarType関数で型を調べる
• Variant型のデータから型を判断する
• If 構文で条件分岐する
• 配列の型を調べる
• Object型のデータについて
• TypeName関数との違いについて
  • VarType関数と、TypeName関数の比較表
  • テストのしやすさ
  • Object 型について
• 関連リンク

「Variant型を使ってるけど、どの型のデータが入っているか調べたい！」や「型によって処理を変えたい」と思ったあなたへ。
この記事では、VarType関数の使い方を丁寧に解説します！

目標リスト

• VarType関数で変数の型を調べられるようになる
• VarType関数でプログラム制御をできるようになる

VarType関数で型を調べる

VarType関数を使うと、指定した値や変数のデータ型を数値で判定できます。
引数には変数だけでなく、数値や文字列を直接指定することも可能です。

Sub SampleVarType1()
    Dim num As Long
    Dim str As String
    
    num = 10
    str = "abc"
    
    Debug.Print VarType(10) = vbInteger
    Debug.Print VarType(num) = vbLong
    Debug.Print VarType(str) = vbString
End Sub

Variant型のデータから型を判断する

Variant型の変数に格納されている実際のデータから、VarType関数はその型を自動で判定します。 Variant型は「どんな型の値でも代入できる」特殊な型のため、 変数の中身によって実際の型が変わります。 そのため、現在どんな型の値が入っているかを確認したいときに、VarType関数が役立ちます。

Sub SampleVarType2()
    Dim var As Variant
    
    '何も代入していないので、Empty になる
    Debug.Print VarType(var) = vbEmpty
    
    '整数を代入したので、Integer型 (10 は Integer)
    var = 10
    Debug.Print VarType(var) = vbInteger
    
    '文字列を代入したので、String型になる
    var = "string"
    Debug.Print VarType(var) = vbString
End Sub

If 構文で条件分岐する

Variant型は、異なる型の値を代入できるため、処理を分けたいときにはVarType関数で中身の型を確認します。

Sub SampleVarType3()
    Dim var As Variant
    
    var = 10      ' var は、Integer型
    var = "ABC"   ' var は、String型
    
    ' var のデータによって処理を制御する
    If VarType(var) = vbString Then
        Debug.Print "var は、String型です"
    ElseIf VarType(var) = vbInteger Then
        Debug.Print "var は、Integer型です"
    End If
End Sub

配列の型を調べる

配列の変数に格納されているデータから型を判断します。
配列変数では、要素ごとの型と配列そのものの型（配列フラグ付き）を区別して確認できます。

Sub SampleVarType3()
    Dim arr(2) As Long
    '配列の１要素の型のチェック
    Debug.Print VarType(arr(0)) = vbLong
    '配列自体の型のチェック
    Debug.Print VarType(arr) = vbLong + vbArray
End Sub

Object型のデータについて

Object型を含む、Workbook型やWorksheet型などのオブジェクト変数は、VarType関数では「Object型」であることしか判別できません。 そのため、VarType関数の戻り値はすべてvbObject（定数値：9）になります。 どの種類のオブジェクトか（WorkbookやRangeなど）を調べたい場合は、TypeName関数を使いましょう。

Sub SampleVarType5()
    Dim var As Object
    Dim ws As Worksheet
    
    Debug.Print VarType(var) = vbObject
    
    Set var = ThisWorkbook
    Debug.Print VarType(var) = vbObject
    
    Set ws = ThisWorkbook.ActiveSheet
    Debug.Print VarType(ws) = vbObject
End Sub

TypeName関数との違い

TypeName関数とVarType関数の使い分けについてです。

VarType関数と、TypeName関数の比較表

VarType関数と、TypeName関数の比較表です。
VarType関数は数値、TypeName関数は文字列で返ります。

テストのしやすさ

VarType関数は、型に応じた数値を戻す関数です。
それに対し、TypeName関数の戻り値は、型の名前を文字列で戻る関数です。
文字列で条件分岐を行うと誤字脱字等によるミスが生じる可能性があります。 このため、TypeName関数はテストに、VarType関数はプログラムの制御に向いています。

Sub SampleTest1()
    Dim num As Long
    
    'VarType関数で型を確認
    If VarType(num) = vbLong Then
        Debug.Print "num は、Long型です"
    End If
    
    'TypeName関数で型を確認
    If TypeName(num) = "Long" Then
        Debug.Print "num は、Long型です"
    End If
End Sub

Object 型について

VarType関数は、Object型、Workbook型等すべて「9」が戻ります。
TypeName関数の場合、参照先のデータを確認して、その型の名前を文字列で戻ります。 このとき、参照が設定されていない（Nothingの）オブジェクト変数に対しては、TypeName関数は "Nothing" という文字列を返します。

Sub SampleTest1()
    Dim wb As Workbook
    
    Debug.Print "【TypeName(wb)】"
    Debug.Print TypeName(wb)
    Debug.Print "【VarType(wb)】"
    Debug.Print VarType(wb)
End Sub

Sub SampleTest2()
    Dim wb As Workbook
    
    Set wb = ThisWorkbook
    Debug.Print "【TypeName(wb)】"
    Debug.Print TypeName(wb)
    Debug.Print "【VarType(wb)】"
    Debug.Print VarType(wb)
End Sub

• TypeName関数で変数の型を調べる方法

• Setとは？ オブジェクト変数の使い方とNothingの意味を解説

• 変数と型について

• 記号を使った「変数の宣言」について