Excel VBAでシートを移動する方法

Contents
• 今回の目標
• 説明
  • シートの移動について
  • Worksheets("シート名").Move
  • Application.ScreenUpdating
• ブック内のシートを移動する
  • シートを特定のシートの左隣へ移動する
  • シートを特定のシートの右隣へ移動する
  • シートを一番左（先頭）へ移動する
  • シートを一番右（最後尾）へ移動する
  • 複数のシートを移動する
  • 移動先が非表示シートだと移動先がおかしくなる？
• 他のブックへシートを移動する
  • 新しいブックを作成してシートを移動する
  • 開いている他のブックにシートを移動する
• 安全にシートを移動する
  • 移動できるか確認して、シートを移動する
• 関連リンク

今回の目標

「マクロでシートを移動したい！」や「安全にシートを移動するにはどうすれば良いの？」と思ったあなたへ。 この記事では、シートを移動する方法や、複数のシートを一度に移動する方法、別のブックにシートを移動する方法等を丁寧に解説します！ 実務で使える具体例つきです。

目標リスト

• シートを移動させられるようになる
• 別のブックへシートを移動できるようになる
• 新しいブックへシートを移動できるようになる
• エラーを発生させずに、シートを移動できるようになる

説明

シートの移動について

Excelマクロでは、シートを移動できます。
シートを移動するとは、ブック内でシートの見出し（シートの下にあるシート名が書かれたタブのこと）の並び順を変えたり、他のブックへシートを切り取ることを言います。
マクロからシートの移動を行うこともでき、複数のシートを同時に移動、他のブックへ移動することができます。

Worksheets("シート名").Move

シートを移動する場合、Worksheets オブジェクトの Move メソッドを使用します。 「Worksheets("シート名").Move」とシート名を指定するか、「Worksheets(1).Move」とインデックス番号でシートを指定する方法が可能です。

メソッドの構文

シートオブジェクト.Move(Before, After)

Move メソッドの引数一覧

Application.ScreenUpdating

「Application.ScreenUpdating」は、Excelの画面の更新を停止させることができます。
画面の更新を止めると、セルにデータを入力してもシート上の画面が変わりません。 主にマクロの高速化に使用しますが、今回は、画面のちらつきを防ぐために使用します。

移動先のシートが非表示の場合、シートの移動に失敗することがあります（この時、エラーはしません）。 そのため、移動先のシートを表示させる → シートを移動する → シートを表示状態を元に戻す、と処理を行います。
詳細は「移動先が非表示シートだと移動先がおかしくなる？」に続きます。

・Excelの画面を更新しない

Application.ScreenUpdating = False

・Excelの画面を更新する

Application.ScreenUpdating = True

他のブックへシートを移動する

新しいブックを作成してシートを移動する

新しいブックを作成してシートを移動する方法です。
移動後は、アクティブなブックが新しいブックになり、同時に移動先のシートがアクティブなシートになります。 実務では移動先のシートを操作することが多いため、それぞれを変数に代入しておくと便利です。

なお、シートオブジェクトを変数に代入した後に、シートを移動、その変数を参照するとエラーが発生します。 移動後にシートオブジェクトを変数へ代入してください。

サンプルコードでは、マクロを実行しているブックの "Sheet3" を新規ブックへ移動します。

Sub SampleSheetMove2_1()
    Dim wb As Workbook
    Dim ws As Worksheet
    
    ' "Sheet3" を新規ブックに移動する
    Worksheets("Sheet3").Move
    
    Set wb = ActiveWorkbook
    Set ws = ActiveSheet
End Sub

開いている他のブックにシートを移動する

開いている他のブックにシートを移動する方法です。
移動先のブックと 移動位置（After / Before）を指定します。 なお、コピー先となるブックをあらかじめ開いておく必要があります。

サンプルコードでは、マクロを実行しているブックの "Sheet3" を "Book1.xlsx" の "Sheet1" の右隣りへ移動します。

Sub SampleSheetMove2_2()
    ' マクロを実行しているブックの "Sheet3" を _
       "Book1.xlsx" の "Sheet1" の右隣りへ移動する
    ThisWorkbook.Worksheets("Sheet3").Move _
        after:=Workbooks("Book1.xlsx").Worksheets("Sheet1")
End Sub

安全にシートを移動する

移動できるか確認してから、シートを移動する

シートを安全に移動するには、次の項目の確認が必要です。

• 移動元のシートは存在するか
• 移動先のシートは存在するか
• 移動元のブックに「ブックの保護」が設定されていないか
• 移動先のブックに「ブックの保護」が設定されていないか
• 移動元のブックの表示シートが１枚の時、そのシートが移動対象か

サンプルコードでは、上記のチェックをそれぞれ関数化して、真偽を確認しています。 シートを移動できなかったとき、理由をメッセージボックスに表示します。

Sub SampleSheetMove3_1()
    
    If MoveWorksheet(ThisWorkbook, "Sheet1", _
            ThisWorkbook, "Sheet22", True) Then
        ' シート移動できた時の処理
    
    Else
        ' シートを移動できなかった時の処理
    
    End If
End Sub

' --------------------------------------------------------------
' シートを移動できるか確認してから移動する
'     ※ 移動できない場合はメッセージボックスを表示する
'   srcWbObj  ：移動元のブックオブジェクト
'   srcWsName ：移動元のシート名
'   destWbObj ：移動先のブックオブジェクト
'   destWsName：移動先のシート名
'   IsBefore ：True／シート前へ移動、
'              False／シート後ろへ移動
'   戻り値：True ／シートを移動できた
'   　　　　False／シートを移動できなかった
'--------------------------------------------------------------
Function MoveWorksheet(ByRef srcWbObj As Workbook, _
            ByRef srcWsName As String, _
            ByRef destWbObj As Workbook, _
            ByRef destWsName As String, _
            ByVal isBefore As Boolean) As Boolean

    On Error GoTo ErrHandler
    Dim flag1 As Boolean, flag2 As Boolean
    Dim flag3 As Boolean, flag4 As Boolean
    Dim flag5 As Boolean
    Dim errMsg As String
    Dim updating As Boolean
    Dim srcWsObj As Worksheet   ' 移動元のシートオブジェクト
    Dim destWsObj As Worksheet  ' 移動先のシートオブジェクト
    Dim destVisi As Long        ' 移動先の表示状態

    updating = Application.ScreenUpdating
    
    ' 移動元のシートが存在するか
    If IsSheetNameUsed(srcWbObj, srcWsName) Then
        flag1 = True
        Set srcWsObj = srcWbObj.Worksheets(srcWsName)
    End If
    ' 移動先のシートが存在するか
    If IsSheetNameUsed(destWbObj, destWsName) Then
        flag2 = True
        Set destWsObj = destWbObj.Worksheets(destWsName)
        destVisi = destWsObj.Visible
    End If
    
    ' 移動元／移動先に「ブックの保護」が掛けられていないか
    flag3 = IsUnProtectBook(srcWbObj)
    flag4 = IsUnProtectBook(destWbObj)
    
    ' 移動元ブックの表示状態のシートが１枚のとき、 _
        その表示状態のシートを他ブックへ移動するか？
    If srcWbObj Is destWbObj Then
        ' 移動元と移動先のブックが同じなら問題ない
        flag5 = True
    ElseIf flag1 Then
        flag5 = IsAllowedToMoveSheet(srcWbObj, srcWsName)
    End If
    
    ' １つでも成立していないフラグがあると、シートを移動できない
    If Not (flag1 And flag2 And flag3 And flag4 And flag5) Then
        ' エラーメッセージの生成１
        errMsg = "エラーが発生しました。" & vbNewLine & _
            "この画面をキャプチャして、" & vbNewLine & _
            "システム管理者にご連絡ください。" & vbNewLine & _
            "ーーーーーーーーーーーーーーーー" & vbNewLine & _
            "シートを移動できませんでした。" & vbNewLine & _
            "● 移動元情報" & vbNewLine & _
            "　・ブック名：" & srcWbObj.name & vbNewLine & _
            "　・シート名：" & srcWsName & vbNewLine & _
            "● 移動先情報" & vbNewLine & _
            "　・ブック名：" & destWbObj.name & vbNewLine & _
            "　・シート名：" & destWsName & vbNewLine & _
            "● 移動できなかった原因"

        If Not flag1 Then errMsg = errMsg & vbNewLine & _
            "　・移動元のシート名［" & srcWsName & "］がありません"
        If Not flag2 Then errMsg = errMsg & vbNewLine & _
            "　・移動先のシート名［" & destWsName & "］がありません"
        If Not flag3 Then errMsg = errMsg & vbNewLine & _
            "　・移動元のブックの保護を解除してください"
        If Not flag4 Then errMsg = errMsg & vbNewLine & _
            "　・移動先のブックの保護を解除してください"
        If Not flag5 And flag1 Then errMsg = errMsg & vbNewLine & _
            "　・表示されているシートが１枚のとき、" & _
                "そのシートは移動できません"
    End If
    
    If errMsg = "" Then
        Application.ScreenUpdating = False
        destWsObj.Visible = xlSheetVisible
        If isBefore Then
            srcWsObj.Move before:=destWsObj
        Else
            srcWsObj.Move after:=destWsObj
        End If
        destWsObj.Visible = destVisi
        MoveWorksheet = True
    Else
        MsgBox errMsg, vbCritical
        MoveWorksheet = False
    End If
    
CleanUp:
    On Error Resume Next
    Application.ScreenUpdating = updating
    If Not destWsObj Is Nothing Then
        destWsObj.Visible = destVisi
    End If
    On Error GoTo 0
    Exit Function
    
ErrHandler:
    ' エラー時の処理
    
    ' お掃除
    Resume CleanUp
End Function

' --------------------------------------------------------------
' ブックに同名のシート名が存在しているか確認する
'   wb   ：確認対象のブックオブジェクト
'   srcWs：移動したいシート名
'   戻り値：True／同名のシート名が存在している
'--------------------------------------------------------------
Function IsSheetNameUsed(ByRef wb As Workbook, _
            ByRef srcWsName As String) As Boolean
    Dim buf As Worksheet
    
    ' ブックを１シートずつ、名前が一致している確認する
    For Each buf In wb.Worksheets
        If buf.name = srcWsName Then
            IsSheetNameUsed = True
            Exit Function
        End If
    Next buf
    IsSheetNameUsed = False
End Function

' --------------------------------------------------------------
' ブックが保護されていないか
'　※ ブックの保護時、シートの追加・削除・移動・名前変更 ができない
'   戻り値：True／ブックが保護されていない
'--------------------------------------------------------------
Function IsUnProtectBook(ByRef wb As Workbook) As Boolean
    IsUnProtectBook = Not wb.ProtectStructure
End Function

' --------------------------------------------------------------
' 表示されているシートが１枚の時、そのシートが移動対象か
'　 ※表示シートが１枚のとき、表示されているシートを移動できない
'  srcWbObj：確認対象のブックオブジェクト
'  srcWs   ：移動したいシート名
'  戻り値：True／移動可能（表示シートが２枚以上 or 移動対象が非表示）
'--------------------------------------------------------------
Function IsAllowedToMoveSheet(ByRef srcWbObj As Workbook, _
                ByRef srcWsName As String) As Boolean
    Dim i As Long
    Dim visibleCount As Long
    
    ' シートの存在確認は呼び出し元で行うこと！
    
    ' 非表示のシートなら、移動可能
    If srcWbObj.Worksheets(srcWsName).Visible <> xlSheetVisible Then
        IsAllowedToMoveSheet = True
        Exit Function
    End If
    
    '表示中のシートをカウントする
    For i = 1 To srcWbObj.Worksheets.Count
        If srcWbObj.Worksheets(i).Visible = xlSheetVisible Then
            visibleCount = visibleCount + 1
            If visibleCount >= 2 Then Exit For
        End If
    Next i
    ' 表示中のシートが２枚以上なら、シートを移動可能
    IsAllowedToMoveSheet = (visibleCount >= 2)
End Function

関連リンク

• 【例外処理】エラートラップの方法

• Setとは？ オブジェクト変数の使い方とNothingの意味を解説

• シートの操作まとめ（サンプルプログラムがメインです）

• シートの表示と非表示を切り替える方法

• シートの保護と解除の方法まとめ

• シート名をつけるときのルールと注意点

• シートを追加する方法

• シートを削除する方法

• シート名を変更する方法

• シートをコピーする方法

• シートを移動する方法（このページです）