【VBA】シート名をつけるときのルールと注意点～地道に学ぶExcelVBA～

シート名に使用できない文字『 :　¥　/　?　*　[　] 』が含まれてないか、InStr関数で確認します。この使用できない文字は、全角／半角かかわらず使用できません。 InStr関数は、第４引数に「vbTextCompare」を指定することで、全角と半角を区別せずに確認できます。ただし、「¥」だけは、全角「￥」と半角「¥」が別文字として扱われるため、個別に確認する必要があります。

　リンク：InStr関数で、半角と全角を区別せずに位置を取得する

サンプルコード

Sub CheckSheetName1()
    Dim forbChars() As Variant   'forb = forbidden
    Dim buf As Variant
    Dim newShNm As String   'ShNm = newSheetName
    Dim num As Long
    Dim forbStr As String
    Dim flag As Boolean
    
    '確認するシート名
    newShNm = "設定 ＊VLOOKUP用"
    
    'シート名に使用できない文字列（全角「￥」が必要）
    forbChars = Array("¥", "￥", "/", ":", "*", "?", "[", "]")
    flag = False
    
    '使用できない文字１つずつ、確認する
    For Each buf In forbChars
        'vbTextCompareを指定して、全角もチェックする
        num = InStr(1, newShNm, buf, vbTextCompare)
        If 0 < num Then
            flag = True
            Exit For
        End If
    Next buf
    
    If flag Then
        Debug.Print "シート名に使用できない文字が含まれています。"
    Else
        Debug.Print "シート名に使用できない文字はありません。"
    End If
End Sub

【実行結果】

シート名に使用できない文字が含まれています。

2.ブックに同名のシート名が存在していないか

ブック内に、同じ名前のシートがすでに存在していないかを確認します。
シートの存在確認は「For構文 + Worksheets.Count」を使う方法と、「For Each構文」を使う方法の2通りがありますが、ここでは後者を使います。

サンプルコード

Sub CheckSheetName2()
    Dim buf As Worksheet
    Dim flag As Boolean
    Dim newShNm As String   'ShNm = newSheetName
    
    '確認するシート名
    newShNm = "Sheet1"
    flag = False
    
    'ブックを１シートずつ、名前が一致していないか確認する
    For Each buf In Worksheets
        If buf.Name = newShNm Then
            flag = True
            Exit For
        End If
    Next buf
    
    If flag Then
        Debug.Print "ブックに同名のシートが存在します。"
    Else
        Debug.Print "ブックに同名のシートはありません。"
    End If
End Sub

【実行結果】

ブックに同名のシートが存在します。

3.シート名は、１文字～３１文字以内か

シート名は、１字～３１字以内である必要があります。
文字数を確認するには、Len関数を使って確認します。

サンプルコード

Sub CheckSheetName3()
    Dim flag1 As Boolean
    Dim flag2 As Boolean
    Dim newShNm As String   'ShNm = newSheetName
    
    '確認するシート名
    newShNm = ""
    
    flag1 = Len(newShNm) = 0
    flag2 = Len(newShNm) > 31
    
    IsInvalidLength = (flag1 Or flag2)
End Sub

【実行結果】

シート名が空文字か、３１文字を超えています

4.シート名の先頭もしくは末尾が ' でないか

シート名の先頭や、末尾を「 ' （アポストロフィ）」にできません。
先頭の１文字を確認するには Left関数、末尾の１文字を確認するには Right関数を使います。

サンプルコード

Sub CheckSheetName4()
    Dim flag1 As Boolean
    Dim flag2 As Boolean
    Dim newShNm As String   'ShNm = newSheetName
    
    '確認するシート名
    newShNm = "'Sheet1"
        
    flag1 = Left(newShNm, 1) = "'"
    flag2 = Right(newShNm, 1) = "'"
    
    If flag1 Or flag2 Then
        Debug.Print "先頭か末尾が「 ' 」です。"
    Else
        Debug.Print "先頭か末尾が「 ' 」ではありません。"
    End If
End Sub

【実行結果】

先頭か末尾が「 ' 」です。

各チェック項目をまとめた関数

安全にシート名を変更するには、上記４つのチェックを行う必要があります。これらの関数をまとめたプログラムです。

サンプルコード

Sub IsPossibleSheetName()
    Dim newShNm As String   'newShNm = newSheetName
    Dim flag1 As Boolean, flag2 As Boolean
    Dim flag3 As Boolean, flag4 As Boolean
    
    newShNm = "'abc?A"
    
    'シート名で使用できない文字が含まれていないか
    flag1 = HasForbiddenChars(newShNm)
    '既に同名のシート名が存在しないか
    flag2 = IsSheetNameUsed(ThisWorkbook, newShNm)
    'シート名の文字の長さは、１字～３１字 か
    flag3 = IsInvalidLength(newShNm)
    'シート名の先頭もしくは末尾を ' にすることはできない
    flag4 = IsEdgeApostrophe(newShNm)
    
    'どれか１つでも当てはまると、シート名には使えません
    If flag1 Or flag2 Or flag3 Or flag4 Then
        Debug.Print newShNm & "は、次の理由によりシート名に使用できません。"
        If flag1 Then Debug.Print "・シート名に使用できない文字が含まれています"
        If flag2 Then Debug.Print "・既に同名のシート名が存在しています"
        If flag3 Then Debug.Print "・シート名の長さが、０文字または３１文字を超えています"
        If flag4 Then Debug.Print "・シート名の先頭もしくは末尾が ' です"
    Else
        Debug.Print newShNm & "はシート名に使用できます。"
    End If
End Sub


'--------------------------------------------------------------
' シート名で使用できない文字が含まれているかを返す
'   newShNm：確認対象のシート名
'   戻り値：True／シート名に使用できない文字が含まれている
'--------------------------------------------------------------
Function HasForbiddenChars(ByVal newShNm As String) As Boolean
    Dim forbChars() As Variant   'forb = forbidden
    Dim buf As Variant
    Dim num As Long
    Dim forbStr As String
    
    'シート名に使用できない文字列
    forbChars = Array("\", "￥", "/", ":", "*", "?", "[", "]")
    
    '使用できない文字１つずつ、確認する
    For Each buf In forbChars
        num = InStr(1, newShNm, buf, vbTextCompare)
        If 0 < num Then
            HasForbiddenChars = True
            Exit Function
        End If
    Next buf
    
    HasForbiddenChars = False
End Function

'--------------------------------------------------------------
' ブックに同名のシート名が既に存在していないか確認する
'   wb     ：確認対象のブック名（シート名を追加／変更するブック）
'   newShNm：確認対象のシート名
'   戻り値：True／同名のシート名が存在している
'--------------------------------------------------------------
Function IsSheetNameUsed(ByRef wb As Workbook, ByRef newShNm As String) As Boolean
    Dim buf As Worksheet
    
    'ブックを１シートずつ、名前が一致していないか確認する
    For Each buf In wb.Worksheets
        If buf.Name = newShNm Then
            IsSheetNameUsed = True
            Exit Function
        End If
    Next buf
    
    IsSheetNameUsed = False
End Function

'--------------------------------------------------------------
' 新しいシート名が１文字～３１文字に収まっているか
'   newShNm：確認対象のシート名
'   戻り値：True／シート名が、０文字または３１文字を超えている
'--------------------------------------------------------------
Function IsInvalidLength(ByRef newShNm As String) As Boolean
    Dim flag1 As Boolean
    Dim flag2 As Boolean
    
    flag1 = Len(newShNm) = 0
    flag2 = Len(newShNm) > 31
    
    IsInvalidLength = (flag1 Or flag2)
End Function

'--------------------------------------------------------------
' シート名の先頭や末尾に ' を使用していないか確認する
'   newShNm：確認対象のシート名
'   戻り値：True／新しいシート名の先頭や末尾が ' である
'--------------------------------------------------------------
Function IsEdgeApostrophe(ByRef newShNm As String) As Boolean
    Dim flag1 As Boolean
    Dim flag2 As Boolean
    
    flag1 = Left(newShNm, 1) = "'"
    flag2 = Right(newShNm, 1) = "'"
    
    IsEdgeApostrophe = (flag1 Or flag2)
End Function

【実行結果】

'abc?Aはシート名に使用できません。
・シート名に使用できない文字が含まれています
・シート名の先頭もしくは末尾が ' です