文字列に下線を設定・解除する方法

Contents
• 今回の目標
• Font.Underline プロパティについて
• 文字列に下線を設定・解除する
• 文字列に下線が設定されているか確認する
  • 簡潔に下線が設定されているか確認する
  • 詳細に下線が設定されているか確認する
• 文字列の一部に下線を設定する
• 関連リンク

この記事では、文字列に下線を設定・解除する方法や、下線が設定されているかを取得する方法を解説します。

目標リスト

• 文字列に下線を設定・解除できるようになる
• 文字列に下線が設定されているか確認できるようになる
• セル内の一部の文字のみ、下線を設定できるようになる

文字列に下線が設定されているか確認する

簡潔に下線が設定されているか確認する

Rangeオブジェクトの Font.Underline で文字列に下線が設定されているか、簡潔に確認します。
「何も下線が設定されていない状態か」を確認することで、種類を問わず下線が設定されているかを確認します。

Sub FontUnderlineSample2_1()

    '二本の下線（テキスト）を設定する / テスト用
    With Range("A1")
        .Value = "地道に学ぶExcelVBA"
        .Font.Underline = xlUnderlineStyleDouble
    End With
    
    'セルA1に下線が引かれているか確認する
    If Range("A1").Font.Underline = xlUnderlineStyleNone Then
        Debug.Print "セルA1に下線が設定されていません。"
    Else
        Debug.Print "セルA1に下線が設定されています。"
    End If
End Sub

詳細に下線が設定されているか確認する

Font.Underline プロパティの設定値を調べて文字列にどの種類の下線が設定されているか確認します。
Select Case 構文を使用します。

Sub FontUnderlineSample2_2()
    '一本の下線（テキスト）を設定する / テスト用
    With Range("A1")
        .Value = "地道に学ぶExcelVBA"
        .Font.Underline = xlUnderlineStyleSingle
    End With
    
    'セルA1に下線が引かれているか確認する
    Select Case Range("A1").Font.Underline
        Case xlUnderlineStyleSingle
            Debug.Print "セルA1に一本の下線（テキスト）が引かれています。"
        Case xlUnderlineStyleSingleAccounting
            Debug.Print "セルA1に一本の下線（セル）が引かれています。"
        Case xlUnderlineStyleDouble
            Debug.Print "セルA1に二本の下線（テキスト）が引かれています。"
        Case xlUnderlineStyleDoubleAccounting
            Debug.Print "セルA1に二本の下線（セル）が引かれています。"
        Case xlUnderlineStyleNone
            Debug.Print "セルA1に下線が設定されていません。"
    End Select
End Sub

文字列の一部に下線を設定する

文字列の一部に下線を設定する場合は、「Range」オブジェクトと「Font.Underline」プロパティの間に『Characters』を追加します。
詳細は別記事（※準備中）で説明しますが、『Characters(開始位置, 文字数)』プロパティを使用します。
例：Range("A1").Characters(3, 2).Font.Underline = True
　→ セルA1の3文字目から2文字のみ(=3文字目と4文字目)、下線を設定する

サンプルコード

Sub FontUnderlineSample3()
    Dim st As Long
    Dim num As Long
    
    'セルA1にテキストを入力して、下線を解除する
    With Range("A1")
        .Value = "期限は「2025年12月31日」までです！"
        .Font.Underline = False
    End With
    
    '下線を設定する位置を決める
    st = InStr(Range("A1"), "「") + 1
    num = InStr(Range("A1"), "」") - st
    
    'セルA1の年月日の部分のみ、二重の下線を設定する
    Range("A1").Characters(st, num).Font.Underline = _
            xlUnderlineStyleDouble
End Sub

【実行結果】
（下の画像のようになります）

• 文字のフォントサイズを変更する方法

• 文字のフォントを変更する方法

• 文字列を太字に変更・太字を解除する方法

• 文字列を斜体に変更・解除する方法

• 文字列の取り消し線を設定・解除する方法

• 文字列に色を設定・解除する方法

• 【セルの操作】Rangeについて