VBAで行を削除する方法（一行・複数行）

Delete メソッドについて

Rows.Delete メソッドとは

Rows.Delete メソッドは、行を削除します。
Rows プロパティで削除する行を指定し、その行に対して削除（Delete メソッド）を実行します。 例えば、Rows("2:4").Delete では、２～４行目の３行が削除され、元の５行目以降の行が３行分上にずれます（元の５行目は２行目、元の６行目は３行目になります）。 なお、行の指定は文字列で指定しますが、１行のみ削除する場合は数値で指定可能です。

Rows.Delete メソッドの構文

３行目を削除する処理です。

Rows("3").Delete

４行目から６行目を削除する処理です。

Rows("4:6").Delete

【別解】Range.Deleteメソッドで行を削除する

Range オブジェクトでも行を削除することが出来ます。
下のプログラムは、３行目を削除します。

Range("3:3").Delete

４～６行目を削除する処理です。

Range("4:6").Delete

一行を削除する

Rows の引数に、どの行を削除するかを指定します。

サンプルコード

Sub DeleteRows1()
    '２行目を削除する
    Rows("2").Delete
End Sub

【実行結果】
（下の画像のようになります）

複数行を削除する

Rows の Delete メソッドを使って複数行を削除します。
Rows("開始行:終了行")の形式で指定します。
例えば、「Rows("2:3").Delete」なら、２行目から３行目を削除します。

サンプルコード

Sub DeleteRows2()
    '２行目～３行目を削除する
    Rows("2:3").Delete
End Sub

【実行結果】
（下の画像のようになります）

セルが含まれる行を削除する

Range オブジェクトの EntireRow プロパティを経由してから Delete メソッドを実行することで、「そのセルを含む行全体」に対して行の削除を行えます。 例えば「Range("B1:C2").EntireRow.Delete」はセルＢ１～Ｃ２を含む行（１行目と２行目）の２行を削除します。

サンプルコード

Sub DeleteRows3()
    'セルＢ１～Ｃ２ の２行（=１～２行目）を削除する
    Range("B1:C2").EntireRow.Delete
End Sub

【実行結果】
（下の画像のようになります）

表のレコードを削除する時の注意点

表のレコードを削除する

「表のある列が特定の値ならレコードを削除するプログラム」を作る場合に注意点があります。
For文などの反復文を使用して、表の上から順に特定のデータなら削除していくとしてしまうと想定と異なる処理をします。 これは、行を削除した時に行が１つ上にずれることが原因で、上にずれたレコードに対し、削除するかの処理を行えないため発生します。
これを回避するには、For文を最終行から開始しなければなりません。つまり、最終行→表の最初の行 と処理をさせます。
下のサンプルでは、表のＤ列が”退会”ならレコードを削除するプログラムです。

サンプルコード

Sub DeleteRows4()
    Const START_ROW As Long = 3
    Dim i As Long
    Dim endRows As Long
    
    endRows = Cells(Rows.Count, 2).End(xlUp).Row
    
    '表の最下行から処理を行うこと！
    For i = endRows To START_ROW Step -1
        If Cells(i, 4) = "退会" Then
            Rows(i).Delete
        End If
    Next i
End Sub

【実行結果】
（下の画像のようになります）

誤ったプログラムにすると…

上から削除すると、削除対象が２件連続した時に残ってしまいます。
試しに、先のプログラムを上から削除するように変更してみます。

サンプルコード（正しく動きません！）

Sub DeleteRows4_BAD()
    Const START_ROW As Long = 3
    Dim i As Long
    Dim endRows As Long
    
    endRows = Cells(Rows.Count, 2).End(xlUp).Row
    
    '表の上から処理しているため正しく処理しない！
    For i = START_ROW To endRows
        If Cells(i, 4) = "退会" Then
            Rows(i).Delete
        End If
    Next i
End Sub

【実行結果】
（下の画像のよう、”退会”の会員が残ってしまいます）

【Excel関数】レコードを削除しても連番にする